現(xiàn)在讓我們用實(shí)驗板上的兩個數(shù)碼管來做一個循環(huán)顯示00～99數(shù)字的實(shí)驗，先來完成必要的硬件部分，

    數(shù)碼管有共陰和共陽的區(qū)分，單片機(jī)都可以進(jìn)行驅(qū)動，但是驅(qū)動的方法卻不同，并且相應(yīng)的0～9的顯示代碼也正好相反。

首先我們來介紹兩位共陽數(shù)碼管的單片機(jī)驅(qū)動方法，電路如下圖：



  
    網(wǎng)友可以看到：P2.6和P2.7端口分別控制數(shù)碼管的十位和個位的供電，當(dāng)相應(yīng)的端口變成低電平時，驅(qū)動相應(yīng)的三極管會導(dǎo)通，+5V通過IN4148二極管和驅(qū)動三極管給數(shù)碼管相應(yīng)的位供電，這時只要P0口送出數(shù)字的顯示代碼，數(shù)碼管就能正常顯示數(shù)字。

    因為要顯示兩位不同的數(shù)字，所以必須用動態(tài)掃描的方法來實(shí)現(xiàn)，就是先個位顯示1毫秒，再十位顯示1毫秒，不斷循環(huán)，這樣只要掃描時間小于1/50秒，就會因為人眼的視覺殘留效應(yīng)，看到兩位不同的數(shù)字穩(wěn)定顯示。

下面我們再介紹一種共陰數(shù)碼管的單片機(jī)驅(qū)動方法，電路如下圖：



    網(wǎng)友可以看到：+5V通過1K的排阻直接給數(shù)碼管的8個段位供電，P2.6和P2.7端口分別控制數(shù)碼管的十位和個位的供電，當(dāng)相應(yīng)的端口變成低電平時，相應(yīng)的位可以吸入電流。單片機(jī)的P0口輸出的數(shù)據(jù)相當(dāng)于將數(shù)碼管不要顯示的數(shù)字段對地短路，這樣數(shù)碼管就會顯示需要的數(shù)字。

    網(wǎng)友可以看到，共陰數(shù)碼管的硬件更簡單，所以在批量生產(chǎn)時，硬件開銷小，節(jié)省PCB面積，減少焊接工作量，降低綜合成本，所以采用共陰數(shù)碼管更有利于批量生產(chǎn)，現(xiàn)在銷售的試驗板都是采用共陰數(shù)碼管了。

以下是用AT89C51實(shí)驗板的兩位數(shù)碼管顯示00～99依次循環(huán)的匯編語言程序

a_bit equ 20h ;數(shù)碼管個位數(shù)存放內(nèi)存位置
b_bit equ 21h ;數(shù)碼管十位數(shù)存放內(nèi)存位置
temp equ 22h ;計數(shù)器數(shù)值存放內(nèi)存位置

star: mov temp,#0 ;初始化計數(shù)器,從0開始
stlop: acall display;調(diào)用顯示子程序
inc temp;對計數(shù)器加1
mov a,temp
cjne a,#100,next ;判斷計數(shù)器是否滿100?
mov temp,#0;滿100就清零重新開始
next: ljmp stlop;不滿就循環(huán)執(zhí)行

;顯示子程序
display: mov a,temp ;將temp中的十六進(jìn)制數(shù)轉(zhuǎn)換成10進(jìn)制
mov b,#10 ;10進(jìn)制/10=10進(jìn)制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個位在b

mov dptr,#numtab ;指定查表啟始地址
mov r0,#4
dpl1: mov r1,#250 ;
dplop: mov a,a_bit ;取個位數(shù)
MOVC A,@A+DPTR ;查個位數(shù)的7段代碼
mov p0,a ;送出個位的7段代碼
clr p2.7 ;開個位顯示
acall d1ms ;顯示162微秒
setb p2.7;關(guān)閉個位顯示,防止鬼影
mov a,b_bit ;取十位數(shù)
MOVC A,@A+DPTR ;查十位數(shù)的7段代碼
mov p0,a ;送出十位的7段代碼
clr p2.6 ;開十位顯示
acall d1ms ;顯示162微秒
setb p2.6;關(guān)閉十位顯示,防止鬼影
djnz r1,dplop ;循環(huán)執(zhí)行250次
djnz r0,dpl1 ;循環(huán)執(zhí)行250X4=1000次
ret

;2+2X80=162微秒,延時按12MHZ計算
D1MS: MOV R7,#80
DJNZ R7,$
RET

;實(shí)驗板上的7段數(shù)碼管0～9數(shù)字的共陰顯示代碼
numtab: DB 0CFH,03H,5DH,5BH,93H,0DAH,0DEH,43H,0DFH,0DBH

end

;如果是共陽數(shù)碼管的顯示代碼
numtab: DB 30H,0FCH,0A2H,0A4H,06CH,25H,21H,0BCH,20H,24H

這是上面程序匯編以后獲得的編程器燒寫文件：

07012216054731.rar