SDA BIT P3.7 ;定義24C02數(shù)據(jù)線
SCL BIT P3.6 ;定義24C02時鐘線
TEMP EQU 30H
DISSTART EQU 40H ;顯示單元首地址
LED_DATA EQU P0 ;數(shù)碼管數(shù)據(jù)口定義
;-----------------------------------------------------
ORG 0000H
AJMP MAIN
ORG 0030H
;-----------------------------------------------------
MAIN:
MOV SP,#60H
MOV P0,#0FFH
MOV P2,#0FFH
MOV TEMP,#00H
ACALL READ_DATA
CALL CONVT
CALL PLAY
MOV A,TEMP
INC A
ACALL WRITE_DATA
M_LOOP:
MOV A,TEMP
CALL CONVT
CALL PLAY
JMP M_LOOP
;-----------------------------------------------------
;寫1字節(jié)數(shù)據(jù)子程序
;-----------------------------------------------------
WRITE_DATA:
MOV R0,#00h ;數(shù)據(jù)寫入首地址
MOV B,A
LCALL WRITE_BYTE ;將計數(shù)值寫入24C02
RET
;-----------------------------------------------------
;讀1字節(jié)數(shù)據(jù)子程序
;-----------------------------------------------------
READ_DATA:
MOV R0,#00H ;讀取的首地址
LCALL READ_BYTE ;讀EEPROM
CALL STOP
MOV TEMP,A
RET
;---------------------------------------------------------
;代碼變換 (HEX TO BCD)
;---------------------------------------------------------
CONVT:
MOV A,TEMP
MOV B,#100
DIV AB
MOV DISSTART+2,A ;百位存放在DISSTART＋2
MOV A,#10
XCH A,B
DIV AB
MOV DISSTART+1,A ;十位存放在DISSTART＋1
MOV DISSTART,B ;個位存放在DISSTART
MOV A,DISSTART+2
JNZ CONVT_END
MOV DISSTART+2,#0AH ;百位為0，關(guān)閉百位顯示
MOV A,DISSTART+1
JNZ CONVT_END
MOV DISSTART+1,#0AH
CONVT_END:
RET
;----------------------------------------------------
;寫操作子程序
;輸入?yún)?shù): R0---要寫入的地址，B---要寫入的數(shù)據(jù)
;----------------------------------------------------
WRITE_BYTE:
CALL START
MOV A,#0A0H
CALL SENDBYTE
CALL WAITACK
MOV A,R0
CALL SENDBYTE
CALL WAITACK
MOV A,B
CALL SENDBYTE
CALL WAITACK
CALL STOP
RET
;----------------------------------------------------
;讀操作子程序
;輸入?yún)?shù)：R0---要讀的字節(jié)地址,
;輸出參數(shù): A---結(jié)果
;----------------------------------------------------
READ_BYTE:
CALL START
MOV A,#0A0H
CALL SENDBYTE
CALL WAITACK
MOV A,R0
CALL SENDBYTE
CALL WAITACK
CALL START
MOV A,#0A1H
CALL SENDBYTE
CALL WAITACK
CALL RCVBYTE
RET
;-----------------------------------------------------
;從IIC總線上接收一個字節(jié)數(shù)據(jù)
;出口參數(shù)：A---接收數(shù)據(jù)存放在A中
;-----------------------------------------------------
RCVBYTE:
MOV R7,#08 ;一個字節(jié)共接收8位數(shù)據(jù)
CLR A
SETB SDA ;釋放SDA數(shù)據(jù)線
R_BYTE:
CLR SCL
NOP
NOP
NOP
NOP
SETB SCL ;啟動一個時鐘周期，讀總線
NOP
NOP
NOP
NOP
MOV C,SDA ;將SDA狀態(tài)讀入C
RLC A ;結(jié)果移入Ａ
SETB SDA ;釋放SDA數(shù)據(jù)線
DJNZ R7,R_BYTE ;判斷8位數(shù)據(jù)是否接收完全？
RET
;----------------------------------------------------
;向IIC總線發(fā)送一個字節(jié)數(shù)據(jù)
;入口參數(shù)：A---待發(fā)送數(shù)據(jù)存放在A中
;----------------------------------------------------
SENDBYTE:
MOV R7,#08
S_BYTE:
RLC A
MOV SDA,C
SETB SCL
NOP
NOP
NOP
NOP
CLR SCL
DJNZ R7,S_BYTE ;8位發(fā)送完畢?
RET
;-----------------------------------------------------
;等待應(yīng)答信號
;等待從機返回一個響應(yīng)信號
;-----------------------------------------------------
WAITACK:
CLR SCL
SETB SDA ;釋放SDA信號線
NOP
NOP
SETB SCL
NOP
NOP
NOP
MOV C,SDA
JC WAITACK ;SDA為低電平，返回了響應(yīng)信號
CLR SDA
CLR SCL
RET
;----------------------------------------------------
;啟動信號子程序
;----------------------------------------------------
START:
SETB SDA
SETB SCL
NOP
CLR SDA
NOP
NOP
NOP
NOP
CLR SCL
RET
;----------------------------------------------------
;停止信號子程序
;----------------------------------------------------
STOP:
CLR SDA
NOP
SETB SCL
NOP
NOP
NOP
NOP
SETB SDA
NOP
NOP
CLR SCL
CLR SDA
RET
;---------------------------------------------------------
PLAY:
MOV R0,#DISSTART ;獲得顯示單元首地址
MOV R1,#07FH ;從第一個數(shù)碼管開始
MOV R2,#03H ;共顯示3位數(shù)碼管
DISP1:
MOV A,@R0 ;獲得當(dāng)前位地址
MOV DPTR,#TAB_NU ;獲得表頭
MOVC A,@A+DPTR ;查表獲得顯示數(shù)據(jù)
MOV LED_DATA,A ;顯示數(shù)據(jù)
MOV P2,R1 ;開始顯示當(dāng)前位
MOV A,R1 ;準(zhǔn)備顯示下一位
RR A
MOV R1,A ;下一位
INC R0 ;取下一個單元地址
LCALL DELAY2MS ;延時 2 MS
DJNZ R2,DISP1 ;重復(fù)顯示下一個
MOV P2,#0FFH ;關(guān)閉顯示
RET ;顯示完成，返回
;---------------------------------------------------------
;延時子程序
;---------------------------------------------------------
DELAY2MS:
MOV R6,#10
DEL1:
MOV R7,#100
DJNZ R7,$
DJNZ R6,DEL1
RET
TAB_NU:
DB 21H,77H,0A2H,62H,74H,68H,28H 73H,20H,60H,0FFH
;---------------------------------------------------------
END
|
|
66821730(技術(shù)支持)
